;+
;PROCEDURE:	get_mfi_st
;PURPOSE:	Gets 3 second resolution data from the WIND MFI magnetic field
;		experiment
;INPUT:	
;	none but will call "timespan" and ask for input if
;	time range not already set
;KEYWORDS:
;	none
;LEGENDS:
;	B3: 3 componenets of B in GSE and nT
;
;CREATED BY: Davin Larson  (modified from version by: Tai Phan)
;FILE:  get_mfi_st.pro  
;VERSION  1.3
;LAST MODIFICATION: 96/08/05
;-


pro get_mfi_st,time_range=range 
     
fname = 'wi_sp_mfi_files'
environvar = 'CDF_DATA_DIR'
dir = getenv(environvar)
if not keyword_set(dir) then $
   message,'Environment variable '+environvar+' is not defined!' 
get_file_names,filenames,TIME_RANGE=range,MASTERFILE=fname,ROOT=dir
ndays = n_elements(filenames)


if ndays eq 0 then begin
   print,"No Hi-res MAG data available from ",time_to_str(range(0)), ' to ', $
   time_to_str(range(1))
   return
endif

for d=0,ndays-1 do begin
   print,'Loading file: ',filenames(d),'...'
   loadcdf_mfi_3s,filenames(d),'Time_PB5',pb5  &   t = pb5_to_time(pb5)
;	print_cdf_info,filenames(d)
	t3= t3time(t)
   loadcdf_mfi_3s,filenames(d),'B3GSE',b3gse
	b3gse= t3array(b3gse)
   loadcdf_mfi_3s,filenames(d),'B3RMSGSE',b3rmsgse
	b3rmsgse= t3array(b3rmsgse)

   if d eq 0 then begin
        t3_tot  = t3
        b3gse_tot = b3gse
        b3rmsgse_tot = b3rmsgse
   endif else begin
        t3_tot  = [t3_tot,t3]
        b3gse_tot = [b3gse_tot,b3gse]
        b3rmsgse_tot = [b3rmsgse_tot,b3rmsgse]
   endelse
endfor


ind = where(b3gse_tot(*,0) lt 1000. and b3gse_tot(*,0) gt -1000.,cnt)

if cnt gt 0 then begin
  t3_tot = t3_tot(ind)
  b3gse_tot = b3gse_tot(ind,*) 
  b3rmsgse_tot = b3rmsgse_tot(ind,*)
endif

labs=['B!dx!n','B!dy!n','B!dz!n']
store_data,'B3',data={ytitle:'B',x:t3_tot,y:b3gse_tot,labels:labs}
store_data,'B3_rms',data={ytitle:'B!drms!n',x:t3_tot,y:b3rmsgse_tot,labels:labs}

end