;+
;PROCEDURE: get_swe
;PURPOSE:
;  Gets key parameter data from the WIND SWE experiment.
;  This routine will produce the following "TPLOT" quantities:
;  Np_swe, Vth_swe,  Vgse_swe
;KEYWORDS:
;  TIME_RANGE:  Optional two element double array specifying time range 
;     to be loaded. See "GET_TIMESPAN" for more default info.
;RESTRICTIONS:
;  This routine expects to find the master file: 'wi_k0_swe_files'
;  In the directory specified by the environment variable: 'CDF_DATA_DIR'
;  See "GET_FILE_NAMES" for more info.
;
;CREATED BY:	Davin Larson
;FILE:  get_swe.pro
;LAST MODIFICATION: 96/06/26
;-

pro get_swe , TIME_RANGE = range  

fname = 'wi_k0_swe_files'
environvar = 'CDF_DATA_DIR'
dir = getenv(environvar)
if not keyword_set(dir) then $
   message,'Environment variable '+environvar+' is not defined!' 

get_file_names,filenames,TIME_RANGE=range,MASTERFILE=fname,ROOT=dir
ndays = n_elements(filenames)

if ndays eq 0 then begin
   message,"No SWE data available from "+ time_to_str(range(0))+ $
   ' to '+time_to_str(range(1))
endif

for d=0,ndays-1 do begin
   print,'Loading file: ',filenames(d),'...'
   loadcdf,filenames(d),'Time_PB5',pb5  &   t = pb5_to_time(pb5)
   loadcdf,filenames(d),'Np'      ,Np
   loadcdf,filenames(d),'THERMAL_SPD',vth
   loadcdf,filenames(d),'V_GSE'   ,vgse
   if d eq 0 then begin
        t_tot  = t
        Np_tot = Np
        vth_tot = vth
        vgse_tot = vgse
   endif else begin
        t_tot  = [t_tot,t]
        Np_tot = [Np_tot,Np]
        vth_tot = [vth_tot,vth]
        vgse_tot = [vgse_tot,vgse]
   endelse
endfor

missing = !values.f_nan

ind = where(np_tot le -1e20)  &  np_tot(ind) = missing
store_data,'Np_swe',data={ytitle:'Np_swe',x:t_tot,y:np_tot}

ind = where(vth_tot le -1e20)  &  vth_tot(ind) = missing
store_data,'Vth_swe',data={ytitle:'Vth_swe',x:t_tot,y:vth_tot}

ind = where(vgse_tot le -1e20)  &  vgse_tot(ind) = missing
store_data,'Vgse_swe',data={ytitle:'Vgse_swe',x:t_tot,y:vgse_tot}

end