;+
;NAME:
; mvn_qlook_init
;PURPOSE:
; Initialization foe MAVEN qlook plotting
;CALLING SEQUENCE:
; mvn_qlook_init, root_data_dir = root_data_dir
;INPUT:
; none
;OUTPUT:
; none
;KEYWORDS:
; root_data_dir = a root_data dir for data, the default is to use the
;                 env variable ROOT_DATA_DIR if it's defined, else it's
;                 /disks/data/ for unix or ~/data, if /disks/data
;                 doesn't exist or c:\data\, for windows. Maven is then
;                 added to the end for the maven directory. 
;                 Don't forget the trailing slash. 
;HISTORY:
; 2013-05-13, jmm, jimm@ssl.berkeley.edu
; $LastChangedBy: jimm $
; $LastChangedDate: 2013-11-05 14:25:06 -0800 (Tue, 05 Nov 2013) $
; $LastChangedRevision: 13494 $
; $URL: svn+ssh://thmsvn@ambrosia.ssl.berkeley.edu/repos/idl_socware/trunk/projects/maven/quicklook/mvn_qlook_init.pro $
;-
Pro mvn_qlook_init, root_data_dir_in = root_data_dir_in, $
                    no_color_setup = no_color_setup,  _extra = _extra

common mvn_qlook_init_private, init_done

If(n_elements(init_done) Eq 0) Then Begin
    init_done = 1
;Add a slash just in case
    If(keyword_set(root_data_dir_in)) Then Begin
        rd = root_data_dir_in[0] 
        ts = strtrim(rd,2)
        ll = strmid(ts, strlen(ts)-1,1)
        If(ll Ne '/' And ll Ne '\') Then ts = ts+'/'
    Endif Else ts = root_data_dir()
    setenv, 'ROOT_DATA_DIR='+ts

    If(~keyword_set(no_color_setup)) Then Begin
        if n_elements(colortable) eq 0 then colortable = 43 ; default color table
        loadct2,colortable
;              Make black on white background
        !p.background = !d.table_size-1 ; White background   (color table 34)
        !p.color=0              ; Black Pen
        !p.font = -1            ; Use default fonts
        !p.charsize = 0.7       ; Smaller font
        if !d.name eq 'WIN' then begin
            device,decompose = 0
        endif
        if !d.name eq 'X' then begin
          ; device,pseudo_color=8  ;fixes color table problem for machines with 24-bit color
            device,decompose = 0
            if !version.os_family eq 'unix' then device,retain=2 ; Unix family does not provide backing store by default
        endif
    Endif
Endif
Return
End