;+
; NAME:
;     starmap_plot_2017_ii
; PURPOSE:
;     plot star map during 08-21-2017 solar eclipse
; CATEGORY:
; CALLING SEQUENCE:
; INPUTS: 
; OPTIONAL (KEYWORD) INPUT PARAMETERS:
; OUTPUTS:  
; COMMON BLOCKS:
; SIDE EFFECTS:
; RESTRICTIONS:   
; MODIFICATION HISTORY:
;     (HH) Jun 30 2011
;-


thick = 1 & xthick = 1 & ythick = 1 & charthick = 1
if !d.name eq 'PS' then !p.font = 0 else !p.font = -1
if !D.name eq 'PS' then begin
  thick=5 & xthick=5 & ythick=5 & charthick = 3
  device,/encapsulate,bits=8,file='starmap_2017.eps'
  device,/color
endif

infil = 'starlist_08_21_2017'
stars = rd_tfile(infil,17,1)
mag = float(stars[7,*])
ra = float(stars[10,*])
dec = float(stars[11,*])
name = string(stars[15,*])+string(' ')+string(stars[16,*])
;
; the sunc variables are SUN's true RA and Dec
;
sunc1 = [15.*10.064305, 11.881827]
sunc2 = [15.*10.068446, 11.859276]
sunc3 = [15.*10.072591, 11.836684]
;
; the srad variables are SUN's semidiameters
;
srad1 = 948.67679/3600.
srad2 = 948.68975/3600.
srad3 = 948.68975/3600.
;
xx = cos(2.*!pi*findgen(1001)/1000)
yy = sin(2.*!pi*findgen(1001)/1000)
plot,ra,dec,psym=3,/iso,xr=[sunc3[0]-2.5,sunc3[0]+2.5],$
  yr=[sunc3[1]-2.5,sunc3[1]+2.5],xst=1,yst=1,$
  xtit='Right Ascension, degrees', ytit='Declination, degrees',$
  thick=thick, xthick=xthick, ythick=ythick, charthick=charthick
nstars = n_elements(stars[0,*])
for ii = 0, nstars-1 do oplot, [ra[ii],ra[ii]], [dec[ii],dec[ii]], $
  psym = sym(1), symsiz= (9-mag[ii])/3, thick=thick
oplot,sunc3[0]+srad3*xx,sunc3[1]+srad3*yy, thick=thick
oplot,sunc2[0]+srad2*xx,sunc2[1]+srad2*yy, thick=thick
oplot,sunc1[0]+srad1*xx,sunc1[1]+srad1*yy, thick=thick
for jj = 149,153 do oplot,[jj,jj],[5,15],lines=1,thick=thick
for jj = 10,14 do oplot,[140,160],[jj,jj],lines=1,thick=thick

xyouts,/data,149.6,12.55,'Nu Leo',charsi=charsi
xyouts,/data,152.9,13.45,'34 Leo',charsi=charsi
xyouts,/data,152.1,12.10,'Regulus',charsi=charsi
xyouts,/data,152.0,10.10,'31 Leo',charsi=charsi
xyouts,/data,151.05,11.45,'GM Leo',charsi=charsi

if !D.name eq 'PS' then device,/close 
end